nopain老大，帮忙给个去掉过多交易信号的模板，好不好！

nopain老大，帮忙给个去掉过多交易信号的模板，好不好！
下面交易信号密集的地方麻烦给写个公式模板吧！
共有3处！看看怎样利用价格波动写个过滤交易信号的的公式模板！
[attach]818[/attach]

[[i] 本帖最后由 人生如梦 于 2008-8-4 15:02 编辑 [/i]]

您的要求就好比要识别盘整和趋势一样，其实这几乎是不可能的。

您需要的是找一个门槛，能够在大多数情况下区分这两种形态。
门槛设得越高，可以过滤更多错误的信号，但是也会越迟缓，看您怎么取舍了

这个没什么模板可言吧?
条件过于简单,信号自然就会多些.关键还是你的思路是什么?想在什么地方出信号.而那些不符合你要求的信号再用条件误句过滤掉就行了.

[quote]原帖由 [i]nopain[/i] 于 2008-8-4 15:03 发表 [url=http://www.tradeblazer.net/forum/redirect.php?goto=findpost&pid=15665&ptid=2689][img]http://www.tradeblazer.net/forum/images/common/back.gif[/img][/url]
您的要求就好比要识别盘整和趋势一样，其实这几乎是不可能的。

您需要的是找一个门槛，能够在大多数情况下区分这两种形态。
门槛设得越高，可以过滤更多错误的信号，但是也会越迟缓，看您怎么取舍了 ... [/quote]

我只是想要一个价格波动范围内不出现信号就行了，这个范围我自己可以调节的！只是我自己写不出这个模板！

Vars
    Numeric MyATR;
Begin
    MyATR = AvgTrueRange(Length);

    if(MyATR< N)
    {
        // 不做交易了
    }

End

老大，这个模板不好，我想要一个以进场价为标准，上下幅度为1%的范围不出现信号 ，或者上下幅度为0.5%的范围不出现信号的公式！

帮个忙吧！还给我加个买入后反向波动1%或0.5%就止损的公式！

自己动手，丰衣足食:lol

晕，别逗了，就靠你教我了啊，我还是个菜鸟呢1

交易系统是一个有机的整体，您说的东西我没法直接写给您啊。

最好把您的想法整理清楚，完整之后，我们在帮您实现吧

[quote]
呵呵，我的交易系统就是一根操盘线，线上买，线下卖，但是在线中间盘整的时候，一定范围内就不要买卖，呵呵！所以要过滤信号！我想要一个以进场价为标准，上下幅度为1%的范围不出现信号 ，或者上下幅度为0.5%的范围不出现信号的公式！还给我加个买入后反向波动1%或0.5%就止损的公式！[/quote]

根据您的表述，我们假定按照日内结算均价线为您的操盘线，示范如下：
[code]
Params
        Numeric Filter(0.5);
        Numeric StopSet(0.5);
Vars
        NumericSeries TotalAmmount;
        NumericSeries TotalVol;
        Numeric AvgLine;
        Bool bInTradeTime;
        NumericSeries UpLine;
        NumericSeries DnLine;
        Numeric MyPrice;
        Numeric TmpStopLine;
Begin
        If(Date!=Date[1])
        {
                TotalVol = Vol;
                TotalAmmount = Vol*(High+Low)/2;
        }Else
        {
                TotalVol = TotalVol[1] + Vol;
                TotalAmmount = TotalAmmount[1] + Vol*(High+Low)/2;
        }
        AvgLine = TotalAmmount/TotalVol;
        UpLine = AvgLine*(1+Filter*0.01);
        DnLine = AvgLine*(1-Filter*0.01);
       
        // 时间限制
        bInTradeTime = (Time >0.0905 && Time < 0.1430);
        If(MarketPosition != 1 && High >= UpLine && bInTradeTime) // 多头开仓
        {
                MyPrice = UpLine;
                If(Open >= UpLine) MyPrice = Open;
                Buy(1,MyPrice);
        }
       
        If(MarketPosition != -1 && Low <= DnLine && bInTradeTime) // 空头开仓
        {
                MyPrice = DnLine;
                If(Open <= DnLine) MyPrice = Open;
                SellShort(1,MyPrice);
        }       
       
        If(MarketPosition == 1) // 多头止损
        {
                TmpStopLine = AvgEntryPrice*(1-StopSet*0.01);
                If( Low <= TmpStopLine)
                {
                        MyPrice = TmpStopLine;
                        If(Open <= TmpStopLine) MyPrice = Open;
                        Sell(1,MyPrice);
                }
        }

        If(MarketPosition == -1) // 空头止损
        {
                TmpStopLine = AvgEntryPrice*(1+StopSet*0.01);
                If( High >= TmpStopLine)
                {
                        MyPrice = TmpStopLine;
                        If(Open >= TmpStopLine) MyPrice = Open;
                        BuyToCover(1,MyPrice);
                }
        }
       
        If(Time >=0.1455) // 收盘平仓
        {
                Sell(1,Open);
                BuyToCover(1,Open);
        }
End
[/code]

老大，你的速度真快，测试一下看好不好，好就有时间请你客，不好就再来烦你！