系统交易论坛 - 开拓者期货自动交易平台 » 系统交易 » 第一次发帖，请教各位高手编写一个交易模型。。。。。

iallen3tz 发表于 2010-7-21 17:08

第一次发帖，请教各位高手编写一个交易模型。。。。。

期市新手，第一次发帖，想利用TB测试一个日线短线模型，希望各位高手帮忙。。。。。
建仓条件： 1.时间>=9:30：00后开始启动交易信号
           2.当价格高于M分钟时间区域的价格最高点，进场建多单1手；
           3.当价格低于N分钟时间区域的价格最低点，进场建空单1手；
平仓条件：时间14:58:00强制平仓；

oliverzrl 发表于 2010-7-21 19:24

//------------------------------------------------------------------------
// 简称: 60
// 名称: 60分钟突破策略
// 类别: 交易指令
// 类型: 其他
// 输出:
//------------------------------------------------------------------------

Params
        Numeric nMins(60);                // N分钟的突破
    Numeric nOffset(3);                // 突破式的价格偏移
Vars
        NumericSeries HighestOf30Min;
    NumericSeries lowestOf30Min;
    Numeric myPrice;
    Numeric MinPoint;
    Numeric lots(1);
Begin
        MinPoint = MinMove*PriceScale;
        If(Date <> Date[1])
        {
                HighestOf30Min = High;
                lowestOf30Min = Low;
        }Else If(Time < 0.0900+nMins*0.0001)
        {
                HighestOf30Min = max(high,HighestOf30Min[1]);
                lowestOf30Min = min(Low,lowestOf30Min[1]);
        }Else
        {
                HighestOf30Min = HighestOf30Min[1];
                lowestOf30Min = lowestOf30Min[1];
        }
        
        If(High >= HighestOf30Min + nOffset*MinPoint && MarketPosition != 1)
        {
                myPrice = HighestOf30Min + nOffset*MinPoint;
                If(Open > myPrice) myPrice = Open;
                Buy(lots,myPrice);
        }

        If(Low <= lowestOf30Min - nOffset*MinPoint && MarketPosition != -1)
        {
                myPrice = lowestOf30Min - nOffset*MinPoint;
                If(Open < myPrice) myPrice = Open;
                SellShort(lots,myPrice);
        }

        If(Time >= 0.1459)
        {
                Sell(lots,Open);
                BuyToCover(lots,Open);
        }
End

//------------------------------------------------------------------------
// 编译版本        GS2004.06.12
// 用户版本        2010/07/08 10:59
// 版权所有        oliverzrl
// 更改声明        TradeBlazer Software保留对TradeBlazer平台
//                        每一版本的TrabeBlazer公式修改和重写的权利
//------------------------------------------------------------------------

查看完整版本: 第一次发帖，请教各位高手编写一个交易模型。。。。。